'--------------------------------------------------------------
'            1WIRE.BAS (c) 2000-2003 MCS Electronics
' demonstrates 1wreset, 1wwrite and 1wread()
' pull-up of 4K7 required to VCC from Portb.2
' DS2401 serial button connected to Portb.2
'--------------------------------------------------------------
'when only bytes are used, use the following lib for smaller code
$lib "mcsbyte.lib"


Config 1wire = Portb.0                                      'use this pin
'On the STK200 jumper B.0 must be inserted
Dim Ar(8) As Byte , A As Byte , I As Byte


Do
  Wait 1
  1wreset                                                   'reset the device
  Print Err                                                 'print error 1 if error
  1wwrite &H33                                              'read ROM command
  For I = 1 To 8
    Ar(i) = 1wread()                                        'place into array
  Next

'You could also read 8 bytes a time by unremarking the next line
'and by deleting the for next above
'Ar(1) = 1wread(8)                                           'read 8 bytes

  For I = 1 To 8
     Print Hex(ar(i));                                      'print output
  Next
  Print                                                     'linefeed
Loop


'NOTE THAT WHEN YOU COMPILE THIS SAMPLE THE CODE WILL RUN TO THIS POINT
'THIS because of the DO LOOP that is never terminated!!!

'New is the possibility to use more than one 1 wire bus
'The following syntax must be used:
For I = 1 To 8
  Ar(i) = 0                                                 'clear array to see that it works
Next

1wreset Pinb , 2                                            'use this port and  pin for the second device
1wwrite &H33 , 1 , Pinb , 2                                 'note that now the number of bytes must be specified!
'1wwrite Ar(1) , 5,pinb,2

'reading is also different
Ar(1) = 1wread(8 , Pinb , 2)                                'read 8 bytes from portB on pin 2

For I = 1 To 8
  Print Hex(ar(i));
Next

'you could create a loop with a variable for the bit number !
For I = 0 To 3                                              'for pin 0-3
  1wreset Pinb , I
  1wwrite &H33 , 1 , Pinb , I
  Ar(1) = 1wread(8 , Pinb , I)
  For A = 1 To 8
    Print Hex(ar(a));
  Next
  Print
Next

End